Logs Insightsのクエリサンプル

ここでは、Logs Insights のクエリサンプルを紹介し、実際にクエリの実行を行います

ロググループの選択

CloudWatch Log Insights を開き、ロググループを選択 をクリックして、クエリ対象のロググループを選択します ここでは、以下の2つを選択します

  • /aws/containerinsights/eksworkshop-eksctl/performance (パフォーマンスログ)
  • /aws/containerinsights/eksworkshop-eksctl/application (アプリケーションログ)

Select WP Pod

コンテナの再起動の平均回数順にソートされる Pod のリスト

STATS avg(number_of_container_restarts) as avg_number_of_container_restarts by PodName
| SORT avg_number_of_container_restarts DESC

リクエストされた Pod と実行中の Pod の比較

fields @timestamp, @message 
| sort @timestamp desc 
| filter Type="Pod" 
| stats min(pod_number_of_containers) as requested, min(pod_number_of_running_containers) as running, ceil(avg(pod_number_of_containers-pod_number_of_running_containers)) as pods_missing by kubernetes.pod_name 
| sort pods_missing desc

クラスターノードの障害数

stats avg(cluster_failed_node_count) as CountOfNodeFailures 
| filter Type="Cluster" 
| sort @timestamp desc

コンテナ名別のアプリケーションログエラー

stats count() as countoferrors by kubernetes.container_name 
| filter stream="stderr" 
| sort countoferrors desc

コンテナ名別のディスク使用状況

stats floor(avg(container_filesystem_usage/1024)) as container_filesystem_usage_avg_kb by InstanceId, kubernetes.container_name, device 
| filter Type="ContainerFS" 
| sort container_filesystem_usage_avg_kb desc

コンテナ名ごとの CPU 使用率

stats pct(container_cpu_usage_total, 50) as CPUPercMedian by kubernetes.container_name 
| filter Type="Container"